[thread display] [new arrival display] [word search] [past log] [管理用]
| Subject | ： input file |
| Date | ： 2006/01/30(Mon) 20:15:46 |
| Contributor | ： Kentaro Harada < > |
!********************************************************************
!*
!* NSLS XRING
!*
!********************************************************************
MOMENTUM=2.8GeV
;
MARK MKN = ()
MKL = ()
MKD = ()
;
MONI PM =()
;
CAVI CAVI=(VOLT= 1.12MV HARM = 30 )
;
BEND B =(L = 2.7 K1 = -0.0724921758 ANGLE = .39269908 E1 = 0.5 E2=0.5)
;
QUAD
Q1 =(L = .45 K1 = -0.675839592 )
Q2 =(L = .8 K1 = 1.069849888 )
Q3 =(L = .4132 K1 = -0.57926284872 )
Q4 =(L = .225 K1 = 0.2923738695 )
;
QUAD Q1 =(L =.45 K1 =-.7822641438882 )
Q2 =(L =.8 K1 =1.077212593357 )
Q3 =(L =.4132 K1 =-.4741679817474 )
Q4 =(L =.225 K1 =.2923740995656 )
;
SEXT SD =(L =.2 K2 =-5.7352107632318 )
SF =(L =.2 K2 =3.6624554033778 )
;
DRIFT D1 =(L = 2.25 )
D2 =(L = 0.685 )
D3 =(L = 0.3484 )
D4 =(L = 0.70825)
D5 =(L = 0.8 )
D7 =(L = 0.7 )
D6 =(L = 0.15 )
;
LINE
NCELLH =(MKN D1 Q1 D2 Q2 D3 Q3 D4
MKD
B
D5 SD D7 SF D6 Q4
MKL)
NCELL =(NCELLH -NCELLH)
RING =(4*NCELL CAVI 4*NCELL )
;
!
! Matching
!
ON LOG;
ON RFSW RADCOD RAD COD FLUC DAPERT;! BIPOL;
FFS;
$FORM = "15.10";
PageWidth = 1999;
ChromCorrect[]:=(
Print["Chromaticity Correction"];
FFS["cell calc emit;"];
{nx0, ny0}=Twiss[{"NX","NY"},"***"]/2/Pi;
FFS["FIT;"];
FFS["NX nx0 2;"];
FFS["NY ny0 2;"];
FFS["DP=0.0001;"];
FFS["FREE S*;"];
FFS["GO;"];
FFS["FITP 1;"];
);
MatchingNcellTune[]:=(
Print["Matching Tune to ",tunex,tuney,"!"];
FFS["cell calc emit;"];
FFS["fit MKD EX 0;"];
FFS["fit MKD EPX 0;"];
FFS["fit NX tunex;"];
FFS["fit NY tuney;"];
! FFS["fit Q2 BX 15"];
! FitValue["Q2","BX",dp_,vgoal_,vnow_]:=If[vnow<5,5,If[vnow>30,30,Null]];
! FFS["fit Q4 BX 15"];
! FitValue["Q4","BX",dp_,vgoal_,vnow_]:=If[vnow<5,5,If[vnow>25,25,Null]];
! FFS["fit Q1 BY 10"];
! FitValue["Q1","BY",dp_,vgoal_,vnow_]:=If[vnow<5,5,If[vnow>25,25,Null]];
! FFS["fit Q2 BY 15"];
! FitValue["Q2","BY",dp_,vgoal_,vnow_]:=If[vnow<5,5,If[vnow>30,30,Null]];
FFS["free Q*;"];
FFS["go;"];
! FFS["SAVE"];
FFS["cell calc"];
);
Do[
Do[
FFS["USE NCELL;"];
MatchingNcellTune[];
ChromCorrect[];
Print[tunex, tuney, Twiss["NX","$$$"]/2/Pi,Twiss["NY","$$$"]/2/Pi,EMITX, LINE["K1","Q1"],LINE["K1","Q2"],LINE["K1","Q3"],LINE["K1","Q4"],LINE["K2","SF"],LINE["K2","SD"]];
datafile = OpenAppend["result.txt"];
Write[datafile,tunex, tuney, Twiss["NX","$$$"]/2/Pi,Twiss["NY","$$$"]/2/Pi,EMITX, LINE["K1","Q1"],LINE["K1","Q2"],LINE["K1","Q3"],LINE["K1","Q4"],LINE["K2","SF"],LINE["K2","SD"]];
Close[datafile];
,{tuney, 0.6, 0.91,0.05}];
,{tunex, 1.1, 1.41, 0.05}];
stop;
stop;